class DipoleSystem {
  
  int posx = 100;
  int posy = 86;
  
  ArrayList all;
  
  int rows = 18;
  int cols = 18;
  
  public float strength = 250;
  public float Inertia = 5000;
  public float friction = 150;
  
  float scanrange = 192.0;
  
  float distx = 20;
  float disty = 20;
  int gridmode = 1;
  
  boolean drawMagnets = true;
  boolean drawField = true;
  boolean drawForce = true;
  boolean playing = false;
  
  
  DipoleSystem() {
    all = new ArrayList();
    init();
  }
  
  void setGrid(int xx, int yy) {
    rows = yy;
    cols = xx;
  }
  
  void reassign() {
    for(int i=0; i<all.size(); i++) {
      Dipole d = (Dipole) all.get(i);
      d.setStrength(strength);
      d.setFriction(friction);
      d.setInertia(Inertia);
      d.checkNbs(all,scanrange); 
    }
  }
  
  void init() {
    // kill all first
    for(int i=all.size()-1; i>=0; i--) {
      Dipole d = (Dipole) all.get(i);
      all.remove(d);
    }
    // create new magnets
    for(int r=0; r<rows; r++) {
      for(int c=0; c<cols; c++) {
        Dipole d = new Dipole(r,c);
        // position
        if(gridmode==0) d.setPos(c*distx,r*disty);
        else if(gridmode==1) d.setPos(c*distx+(r%2)*distx/2,r*(sqrt(sq(distx) - sq(distx/2))));
        //
        d.setStrength(strength);
        d.setFriction(friction);
        d.setInertia(Inertia);
        d.id = all.size();
        all.add(d);
      }
    }
    for(int i=0; i<all.size(); i++) {
      Dipole d = (Dipole) all.get(i);
      d.checkNbs(all,scanrange); 
    }
  }

  void run() {
    if(playing) {
      calculate();
      update();
    }
    render();
  }
  
  
  void calculate() {
    for(int i=0; i<all.size(); i++) {
      Dipole d = (Dipole) all.get(i);
      d.calcB(all); 
    }
  }
  
  void update() {
    for(int i=0; i<all.size(); i++) {
      Dipole d = (Dipole) all.get(i);
      d.update(all); 
    }
  }
  
  void render() {
    pushMatrix();
    translate(posx,posy);
    if(drawField) {
      for(int i=0; i<all.size(); i++) {
        Dipole d = (Dipole) all.get(i);
        d.renderB(0.9);
      }
    }
    if(drawMagnets) {
      for(int i=0; i<all.size(); i++) {
        Dipole d = (Dipole) all.get(i);
        d.render(); 
      }
    }
    popMatrix();
  }
  
}