class Dipole {
  
  float w = 5.0;
  float l = 14.0;
  
  Vector3D pos;
  
  int gr = 0;
  int gc = 0;
  int id = 0;
  
  Vector3D m;          // magnetic dipole
  Vector3D B;          // magnetic field
  float I;   // inertia
  float f;   // friction
  float t;  // torque
  float v;  // angular velocity
  float a;  // angular acceleration
  
  int[] nbs = new int[1];    // neighbours in scanrange
  
  Dipole() {
    
  }
  
  Dipole(int r, int c) {
    nbs[0] = 0;
    gc = c;
    gr = r;
    pos = new Vector3D(0,0,0);
    m = new Vector3D(1,0,0);
    B = new Vector3D(1,0,0);
    // set random angle
    m.rotate2D(random(0,2*PI));
  }
  
  void setPos(float px, float py) {
    pos.setXYZ(px,py,0);
  }
  
  void setStrength(float st) {
    m.setMagnitude(st);
  }
  
  void update(ArrayList all) {
    t = -1 * m.magnitude() * B.magnitude() * (float) Math.sin(m.heading2D()-B.heading2D());
    t -= f * v;
    a = t/I;
    v += a;
    m.rotate2D(v);
  }
  
  void setFriction(float fr) {
    f = fr;
  }
  void setInertia(float in) {
    I = in;
  }
  
  // calculate Magnetic Field based on Neighbours
  void calcB(ArrayList all) {
    B.setXYZ(0,0,0);
    //Vector3D distance = new Vector3D();  
    for(int n=1; n<nbs.length; n++) {
      Dipole d = (Dipole) all.get(nbs[n]);
      Vector3D distance = Vector3D.sub(d.pos,pos); // distance vector
      float multi = vacuum / (4*PI*(pow(distance.magnitude(),3)));
      distance.setMagnitude(d.m.magnitude() * (float) Math.cos(d.m.heading2D()-distance.heading2D())*3);
      distance.sub(d.m);
      distance.mult(multi);
      B.add(distance);
    }
  }
  
  void checkNbs(ArrayList all, float range) {
    nbs = new int[1];
    nbs[0] = 0;
    for(int i=0; i<all.size(); i++) {
      Dipole d = (Dipole) all.get(i);
      if(d.id!=id) {
        if(dist(pos.x,pos.y,d.pos.x,d.pos.y)<range) {
          nbs = append(nbs, d.id);
        }
      }
    }
  }
  
  void renderM(float sc) {
    float arrow = 0.5;
    pushMatrix();
    translate(pos.x*zdist,pos.y*zdist);
    noFill(); stroke(255,100,100);
    pushMatrix();
    rotate(m.heading2D());
    line(0,0,m.magnitude()*sc*zdisp,0);
    line(m.magnitude()*sc*zdisp,0,m.magnitude()*sc*zdisp-arrow,-arrow);
    line(m.magnitude()*sc*zdisp,0,m.magnitude()*sc*zdisp-arrow,arrow);
    popMatrix();
    popMatrix();
  }
  
  void renderB(float sc) {
    float arrow = 0.5;
    pushMatrix();
    translate(pos.x*zdist,pos.y*zdist);
    noFill(); stroke(90);
    pushMatrix();
    rotate(B.heading2D());
    line(0,0,B.magnitude()*sc*zdisp,0);
    line(B.magnitude()*sc*zdisp,0,B.magnitude()*sc*zdisp-arrow,-arrow);
    line(B.magnitude()*sc*zdisp,0,B.magnitude()*sc*zdisp-arrow,arrow);
    popMatrix();
    popMatrix();
  }
  
  void render() {
    pushMatrix();
    translate(pos.x*zdist,pos.y*zdist);
    rotate(m.heading2D());
    noStroke(); 
    pushMatrix();
    scale(zdisp);
    if(colormode==1) {
      fill(255,0,0);
      rect(0,-w/2,l/2,w);
      fill(50,0,255);
      rect(0,-w/2,-l/2,w);
    } else {
      switch(colormode) {
        case(0): fill(100);
                 break;
        case(2): //fill(200-constrain(m.heading2D()*300,0,200));
                 fill(Color.HSBtoRGB(m.heading2D()/(PI*2), 1.0f, 0.80f));
                 break;
        case(3): fill(200-constrain(a*300,0,200));
                 break;
        case(4): fill(200-constrain(v*300,0,200));
                 break;
        case(5): fill(binaryColor(m.heading2D()));
                 break;
      }
      rect(-l/2,-w/2,l,w);
    }
    popMatrix();
    popMatrix();
  }
  
  int binaryColor(float a) {
    int c = 0;
    while(a<0) a+=2*PI;
    while(a>2*PI) a-=2*PI;
    float d = PI/8;
    if(a>=0 && a<d) c = 255;
    else if(a>PI*0.5-d && a<PI*0.5+d) c = 255;
    else if(a>PI-d && a<PI+d) c = 255;
    else if(a>PI*1.5-d && a<PI*1.5+d) c = 255;
    else if(a>PI*2-d && a<=PI*2) c = 255;
    return c;
  }
  
}